Like this article? We recommend
Like this article? We recommend
Like this article? We recommend
The Methods
For the remainder of this article, I’ll focus on the individual methods that comprise the TableViewer class, leaving some comments intact in the code in order to help facilitate understanding. All methods will be pulled out of the class and examined, and then at the end of the article I’ll show the full class code—so don’t worry about trying to paste it all back together from these snippets. If you’re in a hurry and just want to download it, grab the source.zip file instead.
ExtractColor()
The ExtractColor method (see Listing 2) is not integral to the functioning of the class. It’s a sort of helper method that makes it easy to convert from HTML-based color definitions to Flash-based, hexadecimal color definitions. ExtractColor is defined as a private function (as are all the other methods in the class other than the constructor function). This means that it cannot be accessed from outside of the class itself. If we made it public, then we could access it via the object in the Flash file tableView.fla in the form of tb.ExtractColor(someArray). As it is, if we try to do this, Flash will throw an error:
The member is private and cannot be accessed.
Listing 2 The ExtractColor() method.
private function ExtractColor(color:Array):Number {
// removes the # sign and returns hex value as a Number type
if(color) {
var colorStr:String = color[0].toString();
var stringTest:Number = colorStr.indexOf("#");
if (stringTest != -1) {
var colorValue:String = "0x"+colorStr.substring(stringTest+1, colorStr.length);
}
}
var returnColor:Number = parseInt(colorValue);
return returnColor;
}
TableController()
TableController (see Listing 3) makes sure that the methods are called in the proper order. First we call the TableBuilder method (covered in the next section), and then we check for its existence before hurrying off to the next thing. If TableBuilder returns a Boolean value of true, we can proceed.
Listing 3 The TableController() method.
//**********
// TableController method ensures that methods are called in the proper order
//**********
private function TableController() {
var tableBuilt:Boolean = TableBuilder();
if (tableBuilt == true) {
CreateTextBoxes();
CreateAndPositionGrid();
}
}
TableBuilder()
Here we get into a bit more of the heart of the class. The TableBuilder method uses the XPath code to parse the date from the table.xml file into arrays. Using the following syntax, for instance, we can target specific nodes, node values, and attributes using fairly clear, path-like notation:
XPath.selectNodes(TableFile.firstChild, "/table/@width")
In this particular case, XPath is looking for the width attribute within the table tag. As long as our table is valid HTML/XML, this approach will work. Currently in this method we’re searching for values of width, padding, and background color, but this method could be expanded easily to access other attributes as well.
More importantly, however, this method is where we access the values of the rows (<tr>) tags, using the following syntax :
Rows = XPath.selectNodes(TableFile.firstChild, "/table/tr")
The XPath.selectNodes method returns an array, and once we have all the rows in the global Rows array, we can cycle through that array with a for loop and access cell (<td>) values, pushing them onto the global Cells array. Cells then becomes a multidimensional array—an array containing arrays. The first layer contains a reference to the row, each of which then contains a reference to all the cell values for that particular row. Therefore, to access the data in Cells, we’ll employ a nested for loop in the CreateAndPositionGrid() method:
// for each row, get all the values for all the cells
for (var x:Number = 0; x< Rows.length; x++) {
var currentRow:Number = x+1;
// get cells from td and th tags
Cells.push(XPath.selectNodes(TableFile.firstChild, "/table/tr[position() = "+ currentRow +"]/td | /table/tr[position() = "+ currentRow +"]/th")); }
Finally, we do a little rearranging of the orders of the array, based on numeric sorting, to find out what the widest table cell will be and then base all the other cells on that width:
for (var x:Number = 0; x<Cells.length; x++) {
CellsMax.push(Cells[x].length);
CellNumbers.push(Cells[x].length);
}
CellsMax.sort(Array.NUMERIC);
CellsMax.reverse();
CellWidth = Math.floor(TableWidth / CellsMax[0]);
}
TableBuilder() returns a Boolean value, which is used in the TableController() method. If it returns true, the arrays containing rows and cells have been completed and it’s okay to move on to the next step.
Listing 4 shows the full code for TableBuilder().
Listing 4 The TableBuilder() method.
//**********
// gather all of the table data from the table source file and write that data into arrays
//**********
private function TableBuilder():Boolean {
// if TableWidth has not been set, look for a width attribute, capture it, else set the table to 20 less than the Stage.width
if (!TableWidth) {
var tempWidth:Array = XPath.selectNodes(TableFile.firstChild, "/table/@width");
if (tempWidth[0] != undefined) {
TableWidth = parseInt(tempWidth[0]);
} else {
TableWidth = Stage.width - 20;
}
}
// if the table has a padding attribute set, capture it, else set the padding to 0
var tempPadding:Array = XPath.selectNodes(TableFile.firstChild, "/table/@padding");
if (tempPadding[0] != undefined) {
TablePadding = parseInt(tempPadding[0]);
} else {
TablePadding = 0;
}
// get the background color for entire table, else set it to white
var bg = XPath.selectNodes(TableFile.firstChild, "/table/@bgcolor");
if (bg.length > 0 ) {
BackgroundColor = ExtractColor(bg);
} else {
BackgroundColor = 0xffffff;
}
// grab all the rows into an array, then use rows to grab all the cells into an array
Rows = XPath.selectNodes(TableFile.firstChild, "/table/tr");
// for each row, get all the values for all the cells
for (var x:Number = 0; x< Rows.length; x++) {
var currentRow:Number = x+1;
Cells.push(XPath.selectNodes(TableFile.firstChild, "/table/tr[position() = "+ currentRow +"]/td/text()"));
}
//***********************
// goal: determine which row has the most cells so we can calculate how wide to make individual cells
// how:
// push number of cells per row onto CellsTotal
// sort by number :NUMERIC
// reverse to put highest number first...
// use CellWidth to calculate max cell widths...
//***********************
for (var x:Number = 0; x<Cells.length; x++) {
CellsMax.push(Cells[x].length);
CellNumbers.push(Cells[x].length);
}
CellsMax.sort(Array.NUMERIC);
CellsMax.reverse();
CellWidth = Math.floor(TableWidth / CellsMax[0]);
return true;
}
CreateTextBoxes()
In a nod to the notion of separating content from display, the CreateTextBoxes() method is responsible only for creating text boxes and adding text from the Cells array to those boxes (see Listing 5). It doesn’t handle positioning. At this point, all the text boxes are sitting right on top of each other. By cycling through the Cells array with a for loop, we can access the data and then apply it to text boxes. These are appended to the Boxes_mc MovieClip that we initialized back in the constructor. Finally, all the MovieClip paths are pushed onto another array called TextBoxArray, which contains references to all of the text fields we’ve created, and which will be used in the CreateAndPositionGrid() method that’s coming up next.
Listing 5 The CreateTextBoxes() method.
//**********
// create the text boxes based on the Cells multidimensional array (tr1(td1,td2), tr2(td1,td2) ...
//**********
private function CreateTextBoxes() {
for (var x:Number = 0; x<Cells.length; x++) {
// used to create multidimensional array AllTextBoxes at the end of the for loop
var textBoxArray:Array = new Array();
var cellAlignment:String = "center";
var boxArray:Array = new Array();
var textBoxArray:Array = new Array();
// create text boxes and insert values
for (var i:Number = 0; i<Cells[x].length; i++) {
var currentCell:Number = i + 1;
// create text clips and populate
var currentBox:MovieClip = Boxes_mc.createEmptyMovieClip("box"+x+"_"+i, Boxes_mc.getNextHighestDepth());
var currentText:Object = currentBox.createTextField("cell_txt", currentBox.getNextHighestDepth(), 0, 0, CellWidth, 125);
boxArray.push(currentBox);
textBoxArray.push(currentText);
currentText.multiline = true;
currentText.wordWrap = true;
currentText.autoSize = "center";
currentText.border = false;
currentText.html = true;
var formatting = new TextFormat();
formatting.color = 0x333333;
formatting.font = "verdana";
formatting.size = 10;
formatting.align = cellAlignment;
currentText.htmlText = Cells[x][i];
currentText.setTextFormat(formatting);
}
// textBoxArray contains all MovieClip paths for the textFields in a particular row
// push these onto AllTextBoxes to have them all in one place
// for use in CreateAndPositionGrid
AllBoxes.push(boxArray);
AllTexts.push(textBoxArray);
}
}
CreateAndPositionGrid()
At last we’ve arrived at the real engine of this class, the CreateAndPositionGrid() method. To this point, we’ve been preparing, setting up arrays of data, and getting ready. Now it’s time to lay out the text boxes of our "table." Listing 6 shows the full method, after which we’ll examine the details.
Listing 6 The CreateAndPositionGrid() method.
private function CreateAndPositionGrid() {
var rHeight:Number = 0;
var finalRowHeights:Array = new Array();
finalRowHeights.push(0);
var finalCellWidths:Array = new Array();
for (var x:Number = 0; x < Cells.length; x++) {
var colCounter:Number = 0;
var cellHeights:Array = new Array();
var cellWidths:Array = new Array();
for (var i:Number = 0; i < Cells[x].length; i++) {
var curRow:Number = x+1;
var curCell:Number = i+1;
var colspanValue:Array = XPath.selectNodes(TableFile.firstChild, "/table/tr[position() = "+ curRow +"]/td[position() = "+ curCell +"]/@colspan");
var colSpan:Number = 1;
// if colspan exists
if (colspanValue.length != 0) {
colSpan = parseInt(colspanValue[0]);
}
AllBoxes[x][i]._x = (colCounter*CellWidth)*colSpan;
AllBoxes[x][i]._y = rHeight;
var calTextWidth:Number;
if (colspanValue.length != 0) {
colCounter = colSpan;
calTextWidth = colCounter*CellWidth;
AllTexts[x][i]._width = calTextWidth;
} else {
colCounter++;
}
cellHeights.push(AllTexts[x][i]._height);
cellWidths.push(AllTexts[x][i]._width);
}
// sort rowHeights to find the highest cell height
cellHeights.sort(Array.NUMERIC);
cellHeights.reverse();
var curRowMaxHeight:Number = Math.floor(cellHeights[0]);
// increment rHeight with current row’s maximum height
rHeight = rHeight + curRowMaxHeight;
finalRowHeights.push(rHeight);
finalCellWidths.push(cellWidths);
// draw the outer and row borders
Border_mc.lineStyle(1, 0x999999, 100);
Border_mc.moveTo(0, 0);
Border_mc.lineTo(TableWidth, 0);
Border_mc.lineTo(TableWidth, rHeight);
Border_mc.lineTo(0, rHeight);
Border_mc.lineTo(0, 0);
}
// draw inner vertical lines
for (var n:Number = 0; n<finalRowHeights.length; n++) {
Border_mc.lineStyle(1, 0x999999, 100);
var cellCalc:Number = 0;
for (var z:Number = 0; z<finalCellWidths[n].length-1; z++) {
cellCalc = cellCalc + parseInt(finalCellWidths[n][z]);
Border_mc.moveTo(cellCalc, finalRowHeights[n]);
Border_mc.lineTo(cellCalc, finalRowHeights[n+1]);
}
}
}
First, we initialize a few local variables (ones that we’ll use only in this method):
- rHeight indicates row height. We establish it at zero, and we’ll increment it as we go.
- finalRowHeight is where we’ll store our row heights.
- finalCellWidths is the array in which we’ll store cell widths. This is used to draw the vertical lines within the table.
Then we’re back to cycling through an array; in this case, the multidimensional Cells array that was constructed in the TableBuilder() method. The first for loop will give us the rows. The nested loop would give us the particular data for the cells, if that’s what we needed. It isn’t. At this point, what we need is access to column span information as well as column heights and widths, which we access via the AllTexts array that we created in the CreateTextBoxes() method. The idea is to cycle through all of the text boxes we’ve created, gather their heights and widths, and then draw the outer boundaries of the table. If you want, you can comment out the last for loop, the one preceded by the following comment:
// draw inner vertical lines
If you choose to comment out the for loop, however, the table has only an outer boundary and horizontal row dividers. We need that final step to delineate the cells. Another nested for loop, this one evaluates the arrays that we’ve been just building in the previous for loop, finalRowHeights and finalCellWidths, and uses Flash’s drawing API to draw them accordingly, based on those widths and heights.